- the XML declaration must be the first byte
Response.Write "<?xml version=""1.0"" encoding=""UTF-8""?>" & vbCrLf
Response.Write "<urlset xmlns=""http://www.sitemaps.org/schemas/sitemap/0.9"">" & vbCrLf

'----- fixed pages (the same list the PHP carried)
WriteUrl ""
WriteUrl "/Contact-Us"
WriteUrl "/Find-Us"
WriteUrl "/Company-History"
WriteUrl "/Meet-the-Team"
WriteUrl "/Showroom-Tour"
WriteUrl "/Testimonials"
WriteUrl "/Delivery"
WriteUrl "/Choosing"
WriteUrl "/Care-and-Advice"
WriteUrl "/Local-Companies"
WriteUrl "/Blog"
WriteUrl "/Privacy-Policy"

Set rs = Server.CreateObject("ADODB.Recordset")

'----- departments
rs.Open "SELECT Department FROM SubCats WHERE QtyLive <> 0 GROUP BY Department", Conn
Do While Not rs.EOF
	WriteUrl "/Dept/" & UrlSlug(rs("Department"))
	rs.MoveNext
Loop
rs.Close

'----- categories
rs.Open "SELECT Category FROM SubCats WHERE QtyLive <> 0 GROUP BY Category", Conn
Do While Not rs.EOF
	WriteUrl "/" & UrlSlug(rs("Category"))
	rs.MoveNext
Loop
rs.Close

'----- sub-categories
rs.Open "SELECT SubCat FROM SubCats WHERE QtyLive <> 0 GROUP BY SubCat", Conn
Do While Not rs.EOF
	WriteUrl "/" & UrlSlug(rs("SubCat"))
	rs.MoveNext
Loop
rs.Close

'----- brands
rs.Open "SELECT Brand FROM Products WHERE Deleted = 0 AND Live = 1 GROUP BY Brand", Conn
Do While Not rs.EOF
	WriteUrl "/" & UrlSlug(rs("Brand"))
	rs.MoveNext
Loop
rs.Close

'----- products: /ID/Brand/[Range-]Name, as viewR.asp's canonical check builds them
rs.Open "SELECT ID, Brand, `Range`, Name FROM Products WHERE Deleted = 0 AND Live = 1", Conn
Do While Not rs.EOF
	strBrand = UrlSlug(rs("Brand") & "")
	If rs("Range") & "" <> "" Then
		strSlug = UrlSlug(rs("Range") & " " & rs("Name"))
	Else
		strSlug = UrlSlug(rs("Name") & "")
	End If
	WriteUrl "/" & rs("ID") & "/" & strBrand & "/" & strSlug
	rs.MoveNext
Loop
rs.Close
Set rs = Nothing

Response.Write "</urlset>"

Conn.Close
Set Conn = Nothing
%>